在從事使用powerbuilder進行數據庫開發的過程中,常常碰到要使用列表框來選擇數據,但是普通的下拉列表框并沒有提供和數據相連接的方法,而使用數據窗口的子下拉列表框來代替又顯得有些別扭.下面介紹一種好看又好用的方法.
　　可能大家已經想到了吧,使用指針把要連接的數據一條一條地從select 語句的查詢結果中fetch 出來,然后再把數據additem到下拉列表框中去.
　　雖然這也是一種可行的方法,但是他的速度很不能令人滿意,太受數據量的影響.
　　我們可以利用powerbuilder 最推崇的數據窗口技術作為數據庫和下拉列表框連接的橋梁,這種方法即方便快速又安全可靠.
好了,下面制作的下拉列表框,在完成之后會帶給你許多意想不到的方便!

一. 打開powerbuilder的"select user object"畫筆,選擇<new>, 在"new user object"中選擇"Visual"類的"Standard"項并按下<ok>, 在彈出來的"Select Standard Visual Type"對話框中選擇列表中的 "dropdownlistbox"項并按下<ok>. 接著加入一些實例變量,選擇"Declare"菜單項的"Instance Variables.."
加入變量的聲明: datastore ids_user int il_row 并按下<ok>.
我們要對新的對象進行一些限制,在對象的"constructor"事件中加入 程序:
sorted = false //這句非常必要
reset()

二. 好了,現在到了最關鍵的時候了,我們要把數據檢索出來放到ids_user
變量里.
選擇菜單"Declare"項的"User Object Function",在彈出來的對話框
中按下<new>新建一個對象函數命名為:
init
參數有一個:
sqlstr string
返回值為整型:integer
現在我們需要動態地創建datastore
在init函數中寫下:
//integer init(sqlstr string) 開始
long ll_rowcount
long ll_row
string ls_sql
string errors
string ls_return
ids_user = create datastore
//根據sql語句產生數據窗口
ls_return = sqlca.SyntaxFromSQL(sqlstr, 'style(type=grid)',errors)
//sql語句有錯誤
if len(errors) > 0 then
messagebox('錯誤', errors)
return -1
end if
//根據語法動態創建數據窗口
ids_user.create(ls_return)
ids_user.settransobject(sqlca)
ll_rowcount = ids_user.retrieve()
//無數據返回
if ll_rowcount=0 then
return -1
end if
//把數據插入控件
for ll_row = 1 to ll_rowcount
this.additem(string(ids_user.Object.Data[ll_row,1]))
next
//成功返回0
return 0
//integer init(sqlstr string) 結束

現在下拉列表框已經能顯示數據了,但是我們在選擇數據的同時往往
需要的不是它顯示出來的值,比如顯示的是人員姓名,而我們需要的
是工號,難道再使用select語句把需要的數據檢索出來嗎?有了下面的
程序,我們就不必頭痛了.
重復上面建立函數的步驟,新建一個名為getdata的user object函數,
返回值為"any"并在函數中寫下程序:
//any getdata() 開始
any la_return
long ll_row
if text = '' then
return ''
end if
//沒有選擇或沒有檢索到數據
if ids_user.rowcount() = 0 or il_row = 0 then
return ''
end if
//在缺省情況下返回第二列的數據
la_return = ids_user.Object.data[il_row, 2]
return la_return
//andy getdata() 結束

現在還不能返回正確的數據,還需要一個函數setidx(idx int)
程序如下:
//setidx(idx int) 開始
il_row = idx
//setidx(idx int) 結束

現在這個user object已經完成了,我們來做一下試驗試一試.
新建一個應用app_test,一個窗口w_main,按照剛才的方法創
建一個user object:uo_dbdropdownlistbox,放入w_main中
在app_test的open事件中寫下連接數據庫的語句并加上open(w_main)
在w_main的open事件中寫下:
int li_result
li_result = uo_1.init('select name, id from sysobjects')
在uo_1的selectionchanged事件中寫下:
setidx(index)
messagebox('提示', "看" + string(this.getdata()))
這時我們的用戶對象已經能根據選擇的name返回相應的id了.
至于更多的功能,還有待powerbuilder的愛好者們不斷地思考
創造了.如果還想深入討論請和我聯系:fly-back@163.com